rogue
by NUAO

元祖 RPG をPB-100で!?今宵、一次元ローグライクゲームがあなたのポケットにやってくる!

RUN DEG
_:B_@_:I7

ストーリー

あなたは戦士ギルドからの数年にわたる戦闘訓練を受け終わった．

これからギルドの一員となるに当たり、ギルドは試験としてあなたにひとつの課題を与えた．

その内容は、運命の洞窟に赴き、その地下5階で待つ魔物を討伐すること．成功の暁には、あなたはギルドの正式メンバーとして迎えられる．

この試練を達成するため、あなたは家族や友人に別れを告げ、与えられた武器や防具を携えて洞窟へと入っていった．

ストーリーは、ウィキペディアのローグ / ストーリーと目的 の文章を元に一部を変更したものです．(PBロッキー 記)

操作方法

1. 実行前に DEFM 5 と設定し ***VAR:31 の表示を確認しておくこと．
   • この操作は PokecomGO で必要で、Pocket BASIC Simulator では不要です．(PBロッキー 記)

2. shift0 でゲームスタートし、最初に地下1階のフィールドが表示される．自キャラは @．

   RUN DEG
   IA_%@:!(I20
   

3. 初期の自キャラのパラメータは、体力=5、攻撃力=2、満腹度=50．

4. 4←自キャラの移動→6

   階段 % の上では8=上の階へ 2=下の階へ

5. 階を移動すると、新たにマップ、敵、アイテムをランダムに生成する．
6. 敵(A, B, C, ∑, Ω)は階数に応じて1匹/階いる．倒せばその階にはいなくなる． 敵は自キャラに向かってきて、自キャラに隣接すると先制攻撃することがある．

7. 敵に隣接したら4←→6で攻撃でき、乱数(自キャラの体力と攻撃力に応じた値を最大値とする)でダメージを与える．

   敵はカウンター攻撃することがある．敵の体力が0になれば倒れて時々食料を残す．

   バトル後は自キャラの体力が表示される．

8. 移動、攻撃など1アクションごとに食料を1消費し、体力が0.2回復する．

9. アイテムに重なると必ず拾い、対応した効果を得る．

   名称	キャラクタ	効果
   食料	:	満腹度+10
   水薬	!	体力を最大値まで回復
   武器	(	攻撃力が階数だけ up

10. 敵を倒すと、敵の強さ応じて自キャラの体力、体力最大値、攻撃力が上がる．
11. 満腹度が10を切ると自キャラが a となる．満腹度が0になると一歩ごとに体力を1消費する．
12. 自キャラの体力が0になるとゲームオーバー．
13. 地下5階においてラスボス Ω を倒すとゲームクリア．

Pocket BASIC Simulator形式プログラムリスト

[P0]
100 VAC
110 L=1:O=5:A=O:B=2:J=50:SET F0
150 GOSUB #2
200 GOSUB #1:J=J-1:IF J<0;J=0:A=A-1:IF A<0 THEN 720
202 A=A+.2:IF A>O;A=O
205 I$=KEY:IF I$="" THEN 205
210 IF I$="2";IF Q(C)=1;IF L<5;L=L+1:GOTO 150
215 IF I$="8";IF Q(C)=1;IF L>1;L=L-1:GOTO 150
220 IF I$="4";IF H=C-1 THEN 500
225 IF I$="4";IF C>0;C=C-1:GOTO 240
230 IF I$="6";IF H=C+1 THEN 500
235 IF I$="6";IF C<M-1;C=C+1
240 GOTO Q(C)*5+245
245 GOTO 300
250 GOTO 300
255 A=O:GOTO 270
260 J=J+10:GOTO 270
265 B=B+L
270 Q(C)=0
300 IF D<0 THEN 200
305 IF F<RAN#*10 THEN 200
310 P=.3:IF C>H;P=.7
315 IF RAN#<P THEN 330
320 IF H>0;IF H-1<>C;H=H-1
325 GOTO 350
330 IF H<M-1;IF H+1<>C;H=H+1
350 IF ABS(C-H)=1 THEN 510
400 GOTO 200
500 IF RAN#>.5 THEN 600
510 IF G>RAN#*10 THEN 700
520 GOTO 200
600 D=D-(A/2+B)*RAN#
610 IF D>0 THEN 510
620 IF RAN#<.5;IF Q(H)<>1;Q(H)=3
625 H=-2:B=B+E/2:O=O+E*2:A=A+E:IF A>O;A=O
630 IF L=5;PRINT "CLEAR !!    ":END
640 GOTO 200
700 A=A-(D/2+E)*RAN#
710 IF A>0 THEN 200
720 PRINT "GAME OVER...":END

[P1]
90 $=""
100 FOR K=0 TO 8
110 P=C+K-4
120 IF P>-1;IF P<M THEN 150
130 IF P>-2;IF P<M+1;$=$+"I":GOTO 260
140 $=$+" ": GOTO 260
150 GOTO Q(P)*10+160
160 $=$+"_": GOTO 260
170 $=$+"%": GOTO 260
180 $=$+"!": GOTO 260
190 $=$+":": GOTO 260
200 $=$+"("
260 NEXT K
265 PRINT CSR 9;"   ";CSR 8;A;
270 PRINT CSR 0;$;
290 IF D<0 THEN 320
300 $="ABC¥SG¥OM"
305 K=H-C+4
310 IF K>-1;IF K<9;PRINT CSR K;MID (L,1);
320 PRINT CSR 4;"@";:IF J<10;PRINT CSR 4;"a";
400 RETURN

[P2]
100 M=5+INT(RAN#*11)
120 FOR K=0 TO M-1
130 P=RAN#
140 Q(K)=0
150 IF P<.1;Q(K)=3
160 IF P<.05;Q(K)=2
170 IF P<.02;Q(K)=4
180 NEXT K
190 P=INT(RAN#*M):Q(P)=1:C=P
200 P=INT(RAN#*M):IF P=C THEN 200
210 H=P:GOTO (L-1)*10+250
250 D=2:E=1:F=3:G=2:RETURN
260 D=5:E=2:F=5:G=7:RETURN
270 D=10:E=4:F=7:G=9:RETURN
280 D=30:E=10:F=2:G=6:RETURN
290 D=80:E=20:F=1:G=4:RETURN

変数アサイン

行番号マップ

P0

P1 マップ及び敵・自キャラの表示

P2 マップ及び敵の生成

PBロッキーより

Pocket BASIC 用ローグライクゲームはいかがでしたか?

僕は数度の戦死と餓死を経験した後に、クリアすることが出来ました．餓死でゲームオーバーした時は何ともいえない気分でした．

シミュレータ専用について

『rogue』は NUAO 氏がPB-100の宇宙に寄稿してくださったゲーム作品です．

HTML 化はPBロッキーが行い、その際に、他の掲載作とスタイルを統一するための変更を行いました．また、ストーリーはPBロッキーが用意しました．

実機を所有していない NUAO 氏は、本作品の開発を PokecomGO で行ったそうです．寄稿に際して、動作速度の再現性のより高い Pocket BASIC Simulator で実行したところ、FOR 文を使っている「P1 マップ及び敵・自キャラの表示」に時間を要していることが判明しました．

この為に、シミュレータ専用とアナウンスして掲載することにしました．

1次元ローグライクゲームの鉱脈

PB-100 シリーズの Pocket BASIC はグラフィック機能を備えませんが、ゲームユースを意識した豊富なキャラクタを備えていて、時代毎の様々な人気ゲーム作品が無理やりにアレンジ移植されてきました．

ローグの PB-100 シリーズへの移植は、僕の知る限り初めてのことです．本作によっていよいよ、コンピュータ RPG 草創期の人気作品が移植されました．

他の移植作品がグラフィックをキャラクタで代替するのに難儀する中、誰が見てもどこから見てもローグに見える再現性で、無理やり感は皆無です!

2次元のフィールドを探索するローグを、1次元のフィールドにしたら、どのようなプレイ感になるのか？ 作品はこれからの PB-100 用ゲームプログラマに示唆とインスピレーションを与えてくれることと思います．

NUAO 氏の厚意によって本作品は Public Domain で提供されます．存分に研究して改造して PB-100 用ローグライクゲームの可能性に挑戦してみてください！

成功の暁には、あなたはギルドの正式メンバーとして迎えられるでしょう… なんちゃって．

後に続いた作品

Rogue in PB

本作品に触発された、門真なむ氏によるローグライクゲーム作品が2022年8月にリリースされました．満腹度と食料は割愛されていますが、追加要素が多数にも関わらず544ステップに収まっている驚異的作品です．

更新履歴