タイニーRPG最終進化!!
トロネコの大冒険4
by PBロッキー

プログラムリスト

Version 1.3.0、533ステップです．11行に続くのは16行です．

P0
1 E=B:F=G*90:H=SIN F-COS F*9:I=SIN F*9+COS F:FOR J=0 TO 2:F=J*6-1
2 FOR K=1 TO 2:IF FRAC (1ᴇ3*SQR (E+H*K<.5;F=F+K:K(J*ABS O)=2
3 NEXT K:E=B-H+I:I=-I:O(J)=F:NEXT J:PRINT :IF B+H=51+D*46;K=8
4 PRINT A;MID(P,1);MID(7+K-O,1);MID(Q,1);MID(G+1,1);R;CSR 3;
5 IF B≦13+D*43;C=362:D=7:PRINT "♥( Fin":GOTO #1
6 IF K=A+5;O=4:PRINT " ";
7 W=X+7:IF B=C+99;R=INT W*4:PRINT "'";
8 IF RAN#<.1 THEN 16
9 IF KEY="5";IF O≠0;B=B+H:GOTO O*O
10 T=5:IF KEY≠"4";T=3:IF KEY≠"6" THEN 9
11 G=4*FRAC ((G+T)/4:GOTO 1
16 V=O+7+INT ABS (COS B*4:S=V*5:PRINT CSR 3;MID(V+10,1)
17 R(J)=R(J)-INT (RAN#*V(J):PRINT :PRINT R;S;:IF R<1 THEN #1
18 J=RAN#↑RAN#↑RAN#+FRAC π:IF KEY="0";IF J≧1 THEN 1
19 IF S>0 THEN 17
20 IF V(J)=A+9;A=A+1:PRINT "♦"
21 X=X+SQR V/W:GOTO 1
P1
1 A=0:B=C+99:$="↑←↓→ )○>・○ (○<□syπΩS& @¥"

移動画面がもたつきますがバグではありません．なるべく高速な機種、PB-100 等のいわゆる Pocket BASIC Version 1機でのプレイを推奨します．

シミュレータ用リスト

Windows 用アプリ Pocket BASIC Simulator 0.12で動作確認しています．Android 用アプリ PokecomGO - CASIO PB simulator で動作確認しています．

以下のプログラムリストをコピーしてファイルを作成する、または次のリンクからダウンロードします． toronekos-adventure4_v130.bas をダウンロード(831 bytes)

[P0]
1 E=B:F=G*90:H=SIN F-COS F*9:I=SIN F*9+COS F:FOR J=0 TO 2:F=J*6-1
2 FOR K=1 TO 2:IF FRAC (1EX3*SQR (E+H*K<.5;F=F+K:K(J*ABS O)=2
3 NEXT K:E=B-H+I:I=-I:O(J)=F:NEXT J:PRINT :IF B+H=51+D*46;K=8
4 PRINT A;MID(P,1);MID(7+K-O,1);MID(Q,1);MID(G+1,1);R;CSR 3;
5 IF B<=13+D*43;C=362:D=7:PRINT "\HT( Fin":GOTO #1
6 IF K=A+5;O=4:PRINT " ";
7 W=X+7:IF B=C+99;R=INT W*4:PRINT "'";
8 IF RAN#<.1 THEN 16
9 IF KEY="5";IF O<>0;B=B+H:GOTO O*O
10 T=5:IF KEY<>"4";T=3:IF KEY<>"6" THEN 9
11 G=4*FRAC ((G+T)/4:GOTO 1
16 V=O+7+INT ABS (COS B*4:S=V*5:PRINT CSR 3;MID(V+10,1)
17 R(J)=R(J)-INT (RAN#*V(J):PRINT :PRINT R;S;:IF R<1 THEN #1
18 J=RAN#^RAN#^RAN#+FRAC PI:IF KEY="0";IF J>=1 THEN 1
19 IF S>0 THEN 17
20 IF V(J)=A+9;A=A+1:PRINT "\DI"
21 X=X+SQR V/W:GOTO 1
[P1]
1 A=0:B=C+99:$="\UA\LA\DA\RA )\CI>\DT\CI (\CI<\SQsy\PI\OMS& @\\"

既知の問題

ボスからも逃げることができてしまう！

ボスから逃げることができます．今(2024年)は、トロネコは戦士ではなく冒険家ですからそれで良いのかな、と考えていますが、 シミュレータ用(2004年公開)ではボスからの逃走を塞いでいます．良くないな、と考えていた時期もあったようです．

因みにボスは倒しても、または逃げても、白亜の扉を通過する度に出現します．

技術情報

変数表

行番号マップ

今作で解説すべきは1～3行の視界計算だけでしょう．

迷路データは数式から

IF FRAC (1ᴇ3*SQR (E+H*K<.5;F=F+K:K(J*ABS O)=2

まず、壁や通路の情報の入った迷路データの見当たらないないことに驚かれることでしょう．なんと本作では数式から迷路を生成しています． これは昔の雑誌の PB-100 用投稿ゲームでは、しばしば見かけたテクニックです．

2行目の FRAC(1000 × √座標) が0.5より小さければその座標は壁、0.5以上なら通路になります．

しかしこれだけで迷路の形が決まるのではありません． 座標（B）は、X 方向に1歩進む時は+1、または-1、そして Y 方向には+9、または-9しています．この Y 方向の値が変わることでも迷路の形が変わります．

1つの変数で2つのデータを扱う

X・Y 座標の2つの値を1つの変数で扱うのは、これもよく見かけたテクニックです．

その理由は、マップは二次元ですがメモリ上の地形データは線形に格納されていることが多く、地形データを参照する際に、二次元座標から線形座標に変換する計算を省ける利点が考えられます．

一方で、変数から X・Y 座標を取り出すのにコストが掛かります．しかし、このような省メモリテクニックを必要とするゲーム作品では、そもそも X・Y 座標の表示を諦めることが多いと思います．

30文字まで格納できる特殊文字変数（$）は、しばしば迷路データの格納に使われました．16進数的にデータを扱い、1フロアにつき最大6×5マスの迷路を PB-100 に出現させたのでした．

本作では省メモリに加えて、広大で不定形な迷路をつくるのに一役かっているのですが、簡潔に説明するうまい言葉が見つかりません…

3歩進んで2歩下がる

F=G*90:H=SIN F-COS F*9:I=SIN F*9+COS F

1行目で求めている前（H）と左（I）のとる値は、 それぞれ -9,1,9,-1（H）、1,9,-1,-9（I）となります．

これは、トロネコの向き（F）から求めた前方と左方の値になります．（なんかこの辺り、うまい表現じゃありませんね…） 例えば、現在位置（B）に対して左斜め前の座標は B+H+I に、右隣は B-I に、 2マス前は B+2*H になります．

これだけわかれば2～3行や6行、12行の解析は容易でしょう．ちなみに前進は B=B+H でできますね．

J=RAN#^RAN#^RAN#+FRAC π

R(J)=R(J)-INT(RAN#*V(J))